mirror of
https://github.com/PX4/PX4-Autopilot.git
synced 2026-11-22 22:50:49 +08:00
* feat(msg): rename rover throttle setpoint to surface_vehicle_* The throttle setpoint was the last rover topic shared by rovers and boats without the surface_vehicle_* prefix decided in #29524. Rename RoverThrottleSetpoint to SurfaceVehicleThrottleSetpoint and the TYPE_ROVER_THROTTLE_* setpoint types to TYPE_SURFACE_VEHICLE_THROTTLE_*. The type values are unchanged. The topic rename breaks ROS 2 users anyway, so also shorten the fields of the throttle and speed setpoints to x and y: the message name already says what the value is and [@frame Body] states the frame. Assisted-by: Claude:claude-opus-5-5 Signed-off-by: Michael Fritsche <frimi999@gmail.com> * fix(zenoh): bring surface_vehicle rename to the zenoh dds topics * fix(concept): rename rover throttle setpoint to surface_vehicle_* in navigation terminology * fix(tools): update px4-ros2-interface-lib pin * docs(msg): describe sideways fields as omnidirectional, not mecanum The surface vehicle messages are shared by rovers and boats, and the lateral axis applies to any vehicle that can move sideways, not only mecanum rovers. Assisted-by: Claude:claude-opus-5-5 Signed-off-by: Michael Fritsche <frimi999@gmail.com> * docs(ros2): use the surface vehicle setpoint type names of the interface lib The pinned px4-ros2-interface-lib names the rover setpoint types SurfaceVehicle*SetpointType. The table and the example reference still used the old Rover*SetpointType class names, which do not exist in that version. Assisted-by: Claude:claude-opus-5-5 Signed-off-by: Michael Fritsche <frimi999@gmail.com> * feat(msg)!: rename surface vehicle throttle setpoint to thrust setpoint The setpoint is a normalized force command along the body x and y axes, which is a thrust, not a throttle. Throttle stays the name for the motor command the actuator control derives from it. surface_vehicle_throttle_setpoint is now surface_vehicle_thrust_setpoint (SurfaceVehicleThrustSetpoint), and SetpointConfig TYPE_SURFACE_VEHICLE_THROTTLE_* are now TYPE_SURFACE_VEHICLE_THRUST_* (same values). The px4-ros2-interface-lib pin follows the matching rename there. Assisted-by: Claude:claude-opus-5-5 Signed-off-by: Michael Fritsche <frimi999@gmail.com> * fix(tools): update px4-ros2-interface-lib pin * fix(commander): do not enable velocity control for surface vehicle thrust setpoints The SurfaceVehicleThrust* setpoint types enabled the velocity flag, taken over from the original interface lib configuration. Nothing in these types uses velocity, and offboard mode maps the same combinations without it. The flag kept the rover speed controller running: switching from a SurfaceVehicleSpeed* to a SurfaceVehicleThrust* type sets the same flags, so the controllers were not reset and a stale speed setpoint kept overriding the commanded thrust. It also made external modes that only command thrust require a local position estimate. Assisted-by: Claude:claude-opus-5-5 Signed-off-by: Michael Fritsche <frimi999@gmail.com> * docs(msg): apply review suggestions for the surface vehicle setpoints Add long descriptions to the thrust and speed setpoints and the speed status, name modules instead of C++ classes, and use single spaces before field comments. Rename the speed status PID integrals from pid_throttle_* to pid_thrust_*, since the speed controller drives the thrust setpoint. Update the docs and the rover control structure diagram for the thrust setpoint and omnidirectional vehicles, note the Rover*SetpointType names of PX4 v1.17 and v1.18, and add the ROS 2 release note. Assisted-by: Claude:claude-opus-5-5 Signed-off-by: Michael Fritsche <frimi999@gmail.com> --------- Signed-off-by: Michael Fritsche <frimi999@gmail.com>
641 lines
20 KiB
CMake
641 lines
20 KiB
CMake
############################################################################
|
|
#
|
|
# Copyright (c) 2016-2022 PX4 Development Team. All rights reserved.
|
|
#
|
|
# Redistribution and use in source and binary forms, with or without
|
|
# modification, are permitted provided that the following conditions
|
|
# are met:
|
|
#
|
|
# 1. Redistributions of source code must retain the above copyright
|
|
# notice, this list of conditions and the following disclaimer.
|
|
# 2. Redistributions in binary form must reproduce the above copyright
|
|
# notice, this list of conditions and the following disclaimer in
|
|
# the documentation and/or other materials provided with the
|
|
# distribution.
|
|
# 3. Neither the name PX4 nor the names of its contributors may be
|
|
# used to endorse or promote products derived from this software
|
|
# without specific prior written permission.
|
|
#
|
|
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
|
|
# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
|
|
# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
|
|
# FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
|
|
# COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
|
|
# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
|
|
# BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
|
|
# OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
|
|
# AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
|
|
# LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
|
|
# ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
|
|
# POSSIBILITY OF SUCH DAMAGE.
|
|
#
|
|
############################################################################
|
|
|
|
# Support IN_LIST if() operator
|
|
cmake_policy(SET CMP0057 NEW)
|
|
|
|
include(px4_list_make_absolute)
|
|
|
|
set(msg_files
|
|
ActionRequest.msg
|
|
ActuatorArmed.msg
|
|
ActuatorControlsStatus.msg
|
|
ActuatorOutputs.msg
|
|
ActuatorServosTrim.msg
|
|
ActuatorTest.msg
|
|
AdcReport.msg
|
|
Airspeed.msg
|
|
AirspeedWind.msg
|
|
AutotuneAttitudeControlStatus.msg
|
|
BatteryInfo.msg
|
|
ButtonEvent.msg
|
|
CameraCapture.msg
|
|
CameraStatus.msg
|
|
CameraTrigger.msg
|
|
CanInterfaceStatus.msg
|
|
CellularStatus.msg
|
|
CollisionConstraints.msg
|
|
ControlAllocatorStatus.msg
|
|
Cpuload.msg
|
|
DatamanRequest.msg
|
|
DatamanResponse.msg
|
|
DebugArray.msg
|
|
DebugKeyValue.msg
|
|
DebugValue.msg
|
|
DebugVect.msg
|
|
DeviceInformation.msg
|
|
DifferentialPressure.msg
|
|
DistanceSensor.msg
|
|
DistanceSensorModeChangeRequest.msg
|
|
DronecanNodeStatus.msg
|
|
Ekf2Timestamps.msg
|
|
EscEepromRead.msg
|
|
EscEepromWrite.msg
|
|
EscReport.msg
|
|
EscStatus.msg
|
|
EstimatorAidSource1d.msg
|
|
EstimatorAidSource2d.msg
|
|
EstimatorAidSource3d.msg
|
|
EstimatorBias.msg
|
|
EstimatorBias3d.msg
|
|
EstimatorEventFlags.msg
|
|
EstimatorFusionControl.msg
|
|
EstimatorInnovations.msg
|
|
EstimatorSelectorStatus.msg
|
|
EstimatorSensorBias.msg
|
|
EstimatorStates.msg
|
|
EstimatorStatus.msg
|
|
EstimatorStatusFlags.msg
|
|
versioned/Event.msg
|
|
ExternalGimbalManagerStatus.msg
|
|
FigureEightStatus.msg
|
|
FailsafeFlags.msg
|
|
FailureDetectorStatus.msg
|
|
FailureInjection.msg
|
|
FlightPhaseEstimation.msg
|
|
FollowTarget.msg
|
|
FollowTargetEstimator.msg
|
|
FollowTargetStatus.msg
|
|
FuelTankStatus.msg
|
|
FixedWingLateralGuidanceStatus.msg
|
|
FixedWingLateralStatus.msg
|
|
FixedWingRunwayControl.msg
|
|
FixedWingTakeoffStatus.msg
|
|
GeneratorStatus.msg
|
|
GeofenceResult.msg
|
|
GeofenceStatus.msg
|
|
GainCompression.msg
|
|
GimbalControls.msg
|
|
GimbalDeviceAttitudeStatus.msg
|
|
GimbalDeviceInformation.msg
|
|
GimbalDeviceSetAttitude.msg
|
|
GimbalManagerInformation.msg
|
|
GimbalManagerSetAttitude.msg
|
|
GimbalManagerSetManualControl.msg
|
|
GimbalManagerSetPitchyaw.msg
|
|
GimbalManagerStatus.msg
|
|
GpioConfig.msg
|
|
GpioIn.msg
|
|
GpioOut.msg
|
|
GpioRequest.msg
|
|
GpsDump.msg
|
|
Gripper.msg
|
|
HealthReport.msg
|
|
HeaterStatus.msg
|
|
HoverThrustEstimate.msg
|
|
InputRc.msg
|
|
InternalCombustionEngineControl.msg
|
|
InternalCombustionEngineStatus.msg
|
|
IridiumsbdStatus.msg
|
|
IrlockReport.msg
|
|
LandingGear.msg
|
|
LandingGearWheel.msg
|
|
LandingTargetInnovations.msg
|
|
LandingTargetPose.msg
|
|
LaunchDetectionStatus.msg
|
|
LedControl.msg
|
|
LoggerStatus.msg
|
|
LogMessage.msg
|
|
MagnetometerBiasEstimate.msg
|
|
MagWorkerData.msg
|
|
ManualControlSwitches.msg
|
|
MavlinkLog.msg
|
|
MavlinkTunnel.msg
|
|
MessageFormatRequest.msg
|
|
MessageFormatResponse.msg
|
|
Mission.msg
|
|
MissionResult.msg
|
|
MountOrientation.msg
|
|
NavigatorMissionItem.msg
|
|
NavigatorStatus.msg
|
|
NeuralControl.msg
|
|
NfsUp.msg
|
|
NormalizedUnsignedSetpoint.msg
|
|
ObstacleDistance.msg
|
|
OffboardControlMode.msg
|
|
OnboardComputerStatus.msg
|
|
OpenDroneIdArmStatus.msg
|
|
OpenDroneIdBasicId.msg
|
|
OpenDroneIdOperatorId.msg
|
|
OpenDroneIdSelfId.msg
|
|
OpenDroneIdSystem.msg
|
|
OrbitStatus.msg
|
|
OrbTest.msg
|
|
OrbTestLarge.msg
|
|
OrbTestMedium.msg
|
|
ParameterResetRequest.msg
|
|
ParameterSetUsedRequest.msg
|
|
ParameterSetValueRequest.msg
|
|
ParameterSetValueResponse.msg
|
|
ParameterUpdate.msg
|
|
Ping.msg
|
|
PositionControllerLandingStatus.msg
|
|
PositionControllerStatus.msg
|
|
PositionSetpoint.msg
|
|
PositionSetpointTriplet.msg
|
|
PowerButtonState.msg
|
|
PowerMonitor.msg
|
|
PpsCapture.msg
|
|
PurePursuitStatus.msg
|
|
PwmInput.msg
|
|
Px4ioStatus.msg
|
|
QshellReq.msg
|
|
QshellRetval.msg
|
|
RadioStatus.msg
|
|
RangingBeacon.msg
|
|
RateCtrlStatus.msg
|
|
RcChannels.msg
|
|
RcParameterMap.msg
|
|
Rpm.msg
|
|
RtcmData.msg
|
|
RtlStatus.msg
|
|
RtlTimeEstimate.msg
|
|
SatelliteInfo.msg
|
|
SensorAccel.msg
|
|
SensorAccelFifo.msg
|
|
SensorBaro.msg
|
|
SensorCombined.msg
|
|
SensorCorrection.msg
|
|
SensorGnss.msg
|
|
SensorGnssRelative.msg
|
|
SensorGnssRf.msg
|
|
SensorGnssStatus.msg
|
|
SensorGyro.msg
|
|
SensorGyroFft.msg
|
|
SensorGyroFifo.msg
|
|
SensorHygrometer.msg
|
|
SensorMag.msg
|
|
SensorOpticalFlow.msg
|
|
SensorPreflightMag.msg
|
|
SensorSelection.msg
|
|
SensorsStatus.msg
|
|
SensorsStatusGnss.msg
|
|
SensorsStatusImu.msg
|
|
SensorTemp.msg
|
|
SensorUwb.msg
|
|
SensorAirflow.msg
|
|
SurfaceVehicleAttitudeSetpoint.msg
|
|
SurfaceVehicleAttitudeStatus.msg
|
|
SurfaceVehicleCourseSetpoint.msg
|
|
SurfaceVehiclePositionSetpoint.msg
|
|
SurfaceVehicleRateSetpoint.msg
|
|
SurfaceVehicleRateStatus.msg
|
|
SurfaceVehicleSpeedSetpoint.msg
|
|
SurfaceVehicleSpeedStatus.msg
|
|
SurfaceVehicleSteeringSetpoint.msg
|
|
SurfaceVehicleThrustSetpoint.msg
|
|
SystemPower.msg
|
|
TakeoffStatus.msg
|
|
TaskStackInfo.msg
|
|
TecsStatus.msg
|
|
TelemetryStatus.msg
|
|
TiltrotorExtraControls.msg
|
|
TimesyncStatus.msg
|
|
TrajectorySetpoint6dof.msg
|
|
TransponderReport.msg
|
|
TuneControl.msg
|
|
UavcanFirmwareUpdate.msg
|
|
UavcanParameterRequest.msg
|
|
UavcanParameterValue.msg
|
|
UlogStream.msg
|
|
UlogStreamAck.msg
|
|
VehicleAcceleration.msg
|
|
VehicleAirData.msg
|
|
VehicleConstraints.msg
|
|
VehicleControlMode.msg
|
|
VehicleGnss.msg
|
|
VehicleGnssHeading.msg
|
|
VehicleImu.msg
|
|
VehicleImuStatus.msg
|
|
VehicleLocalPositionSetpoint.msg
|
|
VehicleMagnetometer.msg
|
|
VehicleOpticalFlow.msg
|
|
VehicleOpticalFlowVel.msg
|
|
VehicleRoi.msg
|
|
VehicleThrustSetpoint.msg
|
|
VehicleTorqueSetpoint.msg
|
|
VelocityLimits.msg
|
|
Vtx.msg
|
|
WheelEncoders.msg
|
|
YawEstimatorStatus.msg
|
|
versioned/ActuatorMotors.msg
|
|
versioned/ActuatorServos.msg
|
|
versioned/AirspeedValidated.msg
|
|
versioned/ArmingCheckReply.msg
|
|
versioned/ArmingCheckRequest.msg
|
|
versioned/AuxGlobalPosition.msg
|
|
versioned/BatteryStatus.msg
|
|
versioned/ConfigOverrides.msg
|
|
versioned/FixedWingLateralSetpoint.msg
|
|
versioned/FixedWingLongitudinalSetpoint.msg
|
|
versioned/GotoSetpoint.msg
|
|
versioned/HomePosition.msg
|
|
versioned/LateralControlConfiguration.msg
|
|
versioned/LongitudinalControlConfiguration.msg
|
|
versioned/ManualControlSetpoint.msg
|
|
versioned/ModeCompleted.msg
|
|
versioned/RaptorInput.msg
|
|
versioned/RaptorStatus.msg
|
|
versioned/RegisterExtComponentReply.msg
|
|
versioned/RegisterExtComponentRequest.msg
|
|
versioned/SetpointConfig.msg
|
|
versioned/SetpointConfigReply.msg
|
|
versioned/TrajectorySetpoint.msg
|
|
versioned/UnregisterExtComponent.msg
|
|
versioned/VehicleAngularVelocity.msg
|
|
versioned/VehicleAttitude.msg
|
|
versioned/VehicleAttitudeSetpoint.msg
|
|
versioned/VehicleCommandAck.msg
|
|
versioned/VehicleCommand.msg
|
|
versioned/VehicleGlobalPosition.msg
|
|
versioned/VehicleLandDetected.msg
|
|
versioned/VehicleLocalPosition.msg
|
|
versioned/VehicleOdometry.msg
|
|
versioned/VehicleRatesSetpoint.msg
|
|
versioned/VehicleStatus.msg
|
|
versioned/VtolVehicleStatus.msg
|
|
versioned/Wind.msg
|
|
)
|
|
if(CONFIG_GPS_UBX_SPAN)
|
|
list(APPEND msg_files SensorGnssSpectrum.msg)
|
|
endif()
|
|
list(SORT msg_files)
|
|
|
|
if(CONFIG_NAVIGATOR_ADSB)
|
|
list(APPEND msg_files
|
|
DetectAndAvoid.msg
|
|
DetectAndAvoidMostUrgent.msg)
|
|
endif()
|
|
|
|
if(CONFIG_MODULES_VISION_TARGET_ESTIMATOR)
|
|
list(APPEND msg_files
|
|
TargetGnss.msg
|
|
VteInput.msg
|
|
VtePosition.msg
|
|
VteOrientation.msg
|
|
VteAidSource1d.msg
|
|
VteAidSource3d.msg
|
|
VteBiasInitStatus.msg
|
|
FiducialMarkerPosReport.msg
|
|
FiducialMarkerYawReport.msg
|
|
PrecLandStatus.msg
|
|
PrecTakeoffStatus.msg)
|
|
endif()
|
|
|
|
px4_list_make_absolute(msg_files ${CMAKE_CURRENT_SOURCE_DIR} ${msg_files})
|
|
|
|
if(NOT EXTERNAL_MODULES_LOCATION STREQUAL "")
|
|
# Check that the msg directory and the CMakeLists.txt file exists
|
|
if(EXISTS ${EXTERNAL_MODULES_LOCATION}/msg/CMakeLists.txt)
|
|
add_subdirectory(${EXTERNAL_MODULES_LOCATION}/msg external_msg)
|
|
|
|
# Add each of the external message files to the global msg_files list
|
|
foreach(external_msg_file ${config_msg_list_external})
|
|
list(APPEND msg_files ${EXTERNAL_MODULES_LOCATION}/msg/${external_msg_file})
|
|
endforeach()
|
|
endif()
|
|
endif()
|
|
|
|
# headers
|
|
set(msg_out_path ${PX4_BINARY_DIR}/uORB/topics)
|
|
set(ucdr_out_path ${PX4_BINARY_DIR}/uORB/ucdr)
|
|
set(msg_source_out_path ${CMAKE_CURRENT_BINARY_DIR}/topics_sources)
|
|
|
|
set(uorb_headers)
|
|
set(uorb_sources)
|
|
set(uorb_ucdr_headers)
|
|
set(uorb_json_files)
|
|
foreach(msg_file ${msg_files})
|
|
get_filename_component(msg ${msg_file} NAME_WE)
|
|
|
|
# Pascal case to snake case (MsgFile -> msg_file)
|
|
string(REGEX REPLACE "(.)([A-Z][a-z]+)" "\\1_\\2" msg "${msg}")
|
|
string(REGEX REPLACE "([a-z0-9])([A-Z])" "\\1_\\2" msg "${msg}")
|
|
string(TOLOWER "${msg}" msg)
|
|
|
|
list(APPEND uorb_headers ${msg_out_path}/${msg}.h)
|
|
list(APPEND uorb_sources ${msg_source_out_path}/${msg}.cpp)
|
|
list(APPEND uorb_ucdr_headers ${ucdr_out_path}/${msg}.h)
|
|
list(APPEND uorb_json_files ${msg_source_out_path}/${msg}.json)
|
|
endforeach()
|
|
|
|
# set parent scope msg_files for ROS
|
|
set(msg_files ${msg_files} PARENT_SCOPE)
|
|
|
|
# Generate uORB headers
|
|
add_custom_command(
|
|
OUTPUT
|
|
${uorb_headers}
|
|
${msg_out_path}/uORBTopics.hpp
|
|
COMMAND ${PYTHON_EXECUTABLE} ${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_files.py
|
|
--headers
|
|
-f ${msg_files}
|
|
-i ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/versioned
|
|
-o ${msg_out_path}
|
|
-e ${PX4_SOURCE_DIR}/Tools/msg/templates/uorb
|
|
DEPENDS
|
|
${msg_files}
|
|
${PX4_SOURCE_DIR}/Tools/msg/templates/uorb/msg.h.em
|
|
${PX4_SOURCE_DIR}/Tools/msg/templates/uorb/uORBTopics.hpp.em
|
|
${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_files.py
|
|
${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_helper.py
|
|
COMMENT "Generating uORB topic headers"
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
VERBATIM
|
|
)
|
|
add_custom_target(uorb_headers DEPENDS ${uorb_headers})
|
|
|
|
add_custom_command(
|
|
OUTPUT
|
|
${uorb_json_files}
|
|
COMMAND ${PYTHON_EXECUTABLE} ${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_files.py
|
|
--json
|
|
-f ${msg_files}
|
|
-i ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/versioned
|
|
-o ${msg_source_out_path}
|
|
-e ${PX4_SOURCE_DIR}/Tools/msg/templates/uorb
|
|
DEPENDS
|
|
${msg_files}
|
|
${PX4_SOURCE_DIR}/Tools/msg/templates/uorb/msg.json.em
|
|
${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_files.py
|
|
${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_helper.py
|
|
COMMENT "Generating uORB json files"
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
VERBATIM
|
|
)
|
|
add_custom_target(uorb_json_files DEPENDS ${uorb_json_files})
|
|
|
|
set(uorb_message_fields_cpp_file ${msg_source_out_path}/uORBMessageFieldsGenerated.cpp)
|
|
set(uorb_message_fields_header_file ${msg_out_path}/uORBMessageFieldsGenerated.hpp)
|
|
add_custom_command(
|
|
OUTPUT
|
|
${uorb_message_fields_cpp_file}
|
|
${uorb_message_fields_header_file}
|
|
COMMAND ${PYTHON_EXECUTABLE} ${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_compressed_fields.py
|
|
-f ${uorb_json_files}
|
|
--source-output-file ${uorb_message_fields_cpp_file}
|
|
--header-output-file ${uorb_message_fields_header_file}
|
|
DEPENDS
|
|
${uorb_json_files}
|
|
${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_compressed_fields.py
|
|
COMMENT "Generating uORB compressed fields"
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
VERBATIM
|
|
)
|
|
|
|
# Generate microcdr headers
|
|
add_custom_command(
|
|
OUTPUT ${uorb_ucdr_headers}
|
|
COMMAND ${PYTHON_EXECUTABLE} ${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_files.py
|
|
--headers
|
|
-f ${msg_files}
|
|
-i ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/versioned
|
|
-o ${ucdr_out_path}
|
|
-e ${PX4_SOURCE_DIR}/Tools/msg/templates/ucdr
|
|
DEPENDS
|
|
${msg_files}
|
|
${PX4_SOURCE_DIR}/Tools/msg/templates/ucdr/msg.h.em
|
|
${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_files.py
|
|
${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_helper.py
|
|
COMMENT "Generating uORB topic ucdr headers"
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
VERBATIM
|
|
)
|
|
add_custom_target(uorb_ucdr_headers DEPENDS ${uorb_ucdr_headers})
|
|
|
|
# Generate uORB sources
|
|
add_custom_command(
|
|
OUTPUT
|
|
${uorb_sources}
|
|
${msg_source_out_path}/uORBTopics.cpp
|
|
COMMAND ${PYTHON_EXECUTABLE} ${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_files.py
|
|
--sources
|
|
-f ${msg_files}
|
|
-i ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/versioned
|
|
-o ${msg_source_out_path}
|
|
-e ${PX4_SOURCE_DIR}/Tools/msg/templates/uorb
|
|
DEPENDS
|
|
${msg_files}
|
|
${PX4_SOURCE_DIR}/Tools/msg/templates/uorb/msg.cpp.em
|
|
${PX4_SOURCE_DIR}/Tools/msg/templates/uorb/uORBTopics.cpp.em
|
|
${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_files.py
|
|
${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_helper.py
|
|
COMMENT "Generating uORB topic sources"
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
VERBATIM
|
|
)
|
|
|
|
add_library(uorb_msgs ${uorb_headers} ${msg_out_path}/uORBTopics.hpp ${uorb_sources} ${msg_source_out_path}/uORBTopics.cpp ${uorb_message_fields_cpp_file})
|
|
target_link_libraries(uorb_msgs PRIVATE m)
|
|
add_dependencies(uorb_msgs prebuild_targets uorb_headers)
|
|
|
|
if(CONFIG_LIB_CDRSTREAM)
|
|
set(uorb_cdr_idl)
|
|
set(uorb_cdr_idlc)
|
|
set(uorb_cdr_msg)
|
|
set(uorb_cdr_hash)
|
|
set(uorb_cdr_idl_uorb)
|
|
set(idl_include_path ${PX4_BINARY_DIR}/uORB/idl)
|
|
set(idl_out_path ${idl_include_path}/px4/msg)
|
|
set(idl_rihs01_out_path ${idl_include_path}/px4)
|
|
# idlc compiles a copy with escaped identifiers, see msg2idl.py
|
|
set(idlc_include_path ${PX4_BINARY_DIR}/uORB/idlc)
|
|
set(idlc_out_path ${idlc_include_path}/px4/msg)
|
|
set(idl_uorb_path ${PX4_BINARY_DIR}/msg/px4/msg)
|
|
|
|
# Make sure that CycloneDDS has been checkout out
|
|
execute_process(COMMAND git submodule sync src/lib/cdrstream/cyclonedds
|
|
WORKING_DIRECTORY ${PX4_SOURCE_DIR} )
|
|
execute_process(COMMAND git submodule update --init --force src/lib/cdrstream/cyclonedds
|
|
WORKING_DIRECTORY ${PX4_SOURCE_DIR} )
|
|
|
|
# CycloneDDS-tools doesn't ship with the cdrstream-desc feature thus we've to compile idlc from source
|
|
MESSAGE(STATUS "Configuring idlc :" ${CMAKE_CURRENT_BINARY_DIR}/idlc)
|
|
file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/idlc)
|
|
execute_process(COMMAND ${CMAKE_COMMAND} ${PX4_SOURCE_DIR}/src/lib/cdrstream/cyclonedds
|
|
-DCMAKE_C_COMPILER=/usr/bin/gcc
|
|
-DCMAKE_C_COMPILER_LAUNCHER=ccache
|
|
-DCMAKE_CXX_COMPILER_LAUNCHER=ccache
|
|
-DCMAKE_C_FLAGS=-Wno-maybe-uninitialized\ -Wno-unused-parameter
|
|
-DBUILD_EXAMPLES=OFF
|
|
-DENABLE_SSL=OFF
|
|
-DENABLE_SECURITY=OFF
|
|
-DBUILD_DDSPERF=OFF
|
|
-DENABLE_LTO=OFF
|
|
-DENABLE_LIFESPAN=OFF
|
|
-DENABLE_DEADLINE_MISSED=OFF
|
|
-DENABLE_NETWORK_PARTITIONS=oFF
|
|
-DENABLE_SOURCE_SPECIFIC_MULTICAST=oFF
|
|
-DENABLE_IPV6=OFF
|
|
-DENABLE_TYPE_DISCOVERY=OFF
|
|
-DENABLE_TOPIC_DISCOVERY=oFF
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/idlc
|
|
RESULT_VARIABLE CMD_ERROR
|
|
OUTPUT_FILE CMD_OUTPUT )
|
|
MESSAGE(STATUS "Building idlc :" ${CMAKE_CURRENT_BINARY_DIR}/idlc)
|
|
execute_process(COMMAND ${CMAKE_COMMAND} --build . --target idlc
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/idlc
|
|
RESULT_VARIABLE CMD_ERROR
|
|
OUTPUT_FILE CMD_OUTPUT )
|
|
list(APPEND CMAKE_PROGRAM_PATH "${CMAKE_CURRENT_BINARY_DIR}/idlc/bin")
|
|
|
|
# Copy .msg files
|
|
foreach(msg_file ${msg_files})
|
|
get_filename_component(msg ${msg_file} NAME_WE)
|
|
configure_file(${msg_file} ${idl_out_path}/${msg}.msg COPYONLY)
|
|
list(APPEND uorb_cdr_idl ${idl_out_path}/${msg}.idl)
|
|
list(APPEND uorb_cdr_idlc ${idlc_out_path}/${msg}.idl)
|
|
list(APPEND uorb_cdr_msg ${idl_out_path}/${msg}.msg)
|
|
list(APPEND uorb_cdr_hash ${idl_out_path}/${msg}.json)
|
|
list(APPEND uorb_cdr_idl_uorb ${idl_uorb_path}/${msg}.h)
|
|
endforeach()
|
|
|
|
# Generate IDL from .msg using rosidl_adapter
|
|
# Note this a submodule inside PX4 hence no ROS2 installation required
|
|
add_custom_command(
|
|
OUTPUT ${uorb_cdr_idl} ${uorb_cdr_idlc}
|
|
COMMAND ${CMAKE_COMMAND}
|
|
-E env "PYTHONPATH=${PX4_SOURCE_DIR}/src/lib/cdrstream/rosidl/rosidl_adapter:${PX4_SOURCE_DIR}/src/lib/cdrstream/rosidl/rosidl_cli"
|
|
${PYTHON_EXECUTABLE} ${PX4_SOURCE_DIR}/src/lib/cdrstream/msg2idl.py
|
|
--idlc-output-dir ${idlc_out_path}
|
|
${uorb_cdr_msg}
|
|
DEPENDS
|
|
${uorb_cdr_msg}
|
|
${PX4_SOURCE_DIR}/src/lib/cdrstream/msg2idl.py
|
|
git_cyclonedds
|
|
COMMENT "Generating IDL from uORB topic headers"
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
VERBATIM
|
|
)
|
|
|
|
file(CREATE_LINK ${idl_rihs01_out_path} ${idl_include_path}/px4_msgs SYMBOLIC)
|
|
file(MAKE_DIRECTORY ${idlc_out_path})
|
|
file(CREATE_LINK ${idlc_include_path}/px4 ${idlc_include_path}/px4_msgs SYMBOLIC)
|
|
|
|
# Generate IDL from .msg using rosidl_adapter
|
|
# Note this is a submodule inside PX4 hence no ROS2 installation required
|
|
add_custom_command(
|
|
OUTPUT ${uorb_cdr_hash}
|
|
COMMAND ${CMAKE_COMMAND}
|
|
-E env "PYTHONPATH=${PX4_SOURCE_DIR}/src/lib/cdrstream/rosidl/rosidl_adapter:${PX4_SOURCE_DIR}/src/lib/cdrstream/rosidl/rosidl_cli:${PX4_SOURCE_DIR}/src/lib/cdrstream/rosidl/rosidl_parser:${PX4_SOURCE_DIR}/src/lib/cdrstream/rosidl/rosidl_generator_type_description"
|
|
${PYTHON_EXECUTABLE} ${PX4_SOURCE_DIR}/src/lib/cdrstream/idl2rihs01.py
|
|
--output-dir ${idl_rihs01_out_path}
|
|
${uorb_cdr_idl}
|
|
DEPENDS
|
|
${uorb_cdr_idl}
|
|
git_cyclonedds
|
|
COMMENT "Generating RIHS01 hashes from IDL"
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
VERBATIM
|
|
)
|
|
|
|
# Generate C definitions from IDL
|
|
set(CYCLONEDDS_DIR ${PX4_SOURCE_DIR}/src/lib/cdrstream/cyclonedds)
|
|
include("${CYCLONEDDS_DIR}/cmake/Modules/Generate.cmake")
|
|
idlc_generate(TARGET uorb_cdrstream
|
|
FEATURES "cdrstream-desc"
|
|
FILES ${uorb_cdr_idlc}
|
|
INCLUDES ${idlc_include_path}
|
|
BASE_DIR ${idlc_include_path}
|
|
WARNINGS no-implicit-extensibility no-unsupported-annotations)
|
|
target_link_libraries(uorb_cdrstream INTERFACE cdr)
|
|
|
|
# Generate and overwrite IDL header with custom headers for uORB operatability
|
|
# We typedef the IDL struct the uORB struct so that the IDL offset calculate
|
|
# the offset of internal uORB struct for serialization/deserialization
|
|
|
|
# In the future we might want to turn this around let the IDL struct be the leading ABI
|
|
# However we need to remove the padding for logging and remove the re-ordering of fields
|
|
|
|
add_custom_target(
|
|
uorb_idl_header
|
|
COMMAND ${PYTHON_EXECUTABLE} ${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_files.py
|
|
--uorb-idl-header
|
|
-f ${msg_files}
|
|
-i ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/versioned
|
|
-o ${idl_uorb_path}
|
|
-e ${PX4_SOURCE_DIR}/Tools/msg/templates/cdrstream
|
|
DEPENDS
|
|
uorb_cdrstream
|
|
${msg_files}
|
|
${uorb_cdr_hash}
|
|
${PX4_SOURCE_DIR}/Tools/msg/templates/cdrstream/uorb_idl_header.h.em
|
|
${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_files.py
|
|
${PX4_SOURCE_DIR}/Tools/msg/px_generate_uorb_topic_helper.py
|
|
COMMENT "Generating uORB compatible IDL headers"
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
VERBATIM
|
|
)
|
|
add_dependencies(uorb_msgs uorb_idl_header)
|
|
|
|
# Compile all CDR compatible message defnitions
|
|
target_link_libraries(uorb_msgs PRIVATE uorb_cdrstream )
|
|
endif()
|
|
|
|
if(CONFIG_MODULES_ZENOH)
|
|
# The Zenoh Kconfig.topics catalog is generated into the build tree in
|
|
# cmake/kconfig.cmake (it must exist before Kconfig is parsed). Here we only
|
|
# generate the per-board publisher/subscriber factory.
|
|
add_custom_command(
|
|
OUTPUT
|
|
${PX4_BINARY_DIR}/src/modules/zenoh/uorb_pubsub_factory.hpp
|
|
COMMAND ${PYTHON_EXECUTABLE} ${PX4_SOURCE_DIR}/Tools/zenoh/px_generate_zenoh_topic_files.py
|
|
--zenoh-pub-sub
|
|
-f ${msg_files}
|
|
-o ${PX4_BINARY_DIR}/src/modules/zenoh/
|
|
-e ${PX4_SOURCE_DIR}/Tools/zenoh/templates/zenoh
|
|
--rihs ${idl_rihs01_out_path}
|
|
DEPENDS
|
|
${msg_files}
|
|
${uorb_cdr_hash}
|
|
${PX4_SOURCE_DIR}/Tools/zenoh/templates/zenoh/uorb_pubsub_factory.hpp.em
|
|
${PX4_SOURCE_DIR}/Tools/zenoh/px_generate_zenoh_topic_files.py
|
|
COMMENT "Generating Zenoh Topic Code"
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
VERBATIM
|
|
)
|
|
add_custom_target(zenoh_topics
|
|
DEPENDS ${PX4_BINARY_DIR}/src/modules/zenoh/uorb_pubsub_factory.hpp
|
|
)
|
|
endif()
|